FYI: InterNIC/MERIT/RIPE database exchange format

[Marten Terpstra <]

Please find below the exchange format as agreed with InterNIC, MERIT and
RIPE. just for your information.

-Marten


              WHOIS Database Transfer Parse Syntax 1.0
                ------------------------------------

Note: Brackets [] enclose subrules, with  a prefix indicating
optionality and repetition as follows:

  "0[]"  - optional                    "1[]"   - required
  "0*[]" - none or any number          "1*[]"  - at least one

--------------------------- LANGUAGE ----------------------------------

<file> ::= 1[<version>] 1*[<record>] 1[<eof>]
<version> ::= WDB_version: <version_no>
<version_no> ::= 1.0
<record> ::= <begin_data> <data>
<begin_data> ::= ---
<eof> ::= END OF FILE
<data> ::= <network> | <domain> | <host> | <individual> | <as>

<network> ::= 1[<network_data>] 1*[<contact>] 0*[<inaddr_server>] 
              1[<update_information>]

<domain> ::= 1[<domain_data>] 1*[<dom_contact>] 0*[<dns_server>] 
             1[<update_information>]

<as>    ::= 1[<as_data>] 1*[<as_contact>] 1[<update_information>]

<individual> ::= 1[<individual_data>] 1[<update_information>]

<host> ::= 1[<host_data>] 1*[<contact>] 1[<update_information>]

/*******
  network-specific information 
*******/

<network_data> :: = 1[<netip_type>] 1[<netname>] 0[<network_type>]
                    1[<activated>] 0[nic_handle] 1[<organization>]
<netip_type> :: <netip_addr> | <netblk>
<netip_addr> ::= ntnum: <datum>
<netblk> ::= ntsblk: <datum>
             nteblk: <datum>
<netname> ::= ntnam: <datum>
<network_type> ::= ntype: <ntype_data>
<ntype_data> ::= Research | Defense | Government | Commercial
<inaddr_server> := inaddr-server: <host_key>

/*******
  domain-specific information 
*******/

<domain_data> ::= 1[<dom_name>] 1[<parentdom>] 0[nic_handle] 1[<organization>]
<parentdom> ::= pdom: <parentdom_type>
<parentdom_type> ::= COM | EDU | ROOT | NET | ORG | GOV | US
<dom_name> ::= dnam: <datum>
<dom_contact> ::= <contact> | <zone_contact>
<zone_contact> ::= zone-c: <email-address> | <nic_handle>
<dns_server> := dns-server: <host_key>

/*******
  as-specific information
*******/

<as_data> :: = 1[<as_type>] 0[<as_name>] 0*[<asin>] 0*[<asout>]
                0*[<asdefault>] 1[<activated>] 0[nic_handle] 1[<organization>]
<as_type> :: <as_number> | <as_block>
<as_number> ::= asnum: <datum>
<as_block> ::= as_sblk: <datum>
                as_eblk: <datum>
<as_name> ::= asname: <datum>
<asin> ::= asin: <datum>
<asout> ::= asout: <datum>
<asdefault> ::= asdefault: <datum>
<as_contact> ::= <contact> | <as_guardian>
<as_guardian> ::= asguardian: <datum>

/*******
  host-specific information 
*******/

<host_data> ::= 1[<hostname>] 1*[<ip_addr>] 0[nic_handle] 0*[<nickname>]
                0[<cputype>] 0[<opsys>] 0[<protocols>] 0[<hostmail>] 
                1[<organization>]
<hostname> ::= hname: <datum>
<ip_addr> ::= ipaddr: <datum>
<nickname> ::= nname: <datum>
<cputype> ::= cpu: <datum>
<opsys> ::= opsys: <datum>
<protocols> ::= proto: <datum>
<hostmail> ::= hmail: <datum>
<host_contact> ::= <coordinator> | <altpoc>
<coordinator> ::= coord:  <datum>
<altpoc> ::= altpoc: <datum>

/*******
  individual-specific information 
*******/

<individual_data> ::= 1[<name>] 0[nic_handle] 1[<organization>]
                 1*[mailbox] 0*[<phone>] 0*[<fax>] 
<name> ::= <name_components> | <whole_name>
<name_components> ::= 1[<last_name>] 1[<first_name>] 0[<middle_name>]
                 0[<name_suffix>] 0[title]
<last_name> ::= lname: <datum>
<first_name> ::= fname: <datum>
<middle_name> ::= mname: <datum>
<name_suffix> ::= nmsuff: <datum>
<title> ::= ttle: <datum>
<whole_name> ::= whname: <datum>
<mailbox> ::= mbox: <datum>
<phone> ::= phne: <datum>
<fax> ::= fax: <datum>

/********
  update information
*********/

<update_information>::= 1[<name_date>] 1[<location>] 1[<maintainer>]
           0*[<update_notify>]  0[<op_type>]
<name_date> ::= updt: <datum>
<location> ::= source: <place>
<place> ::= RIPE | MERIT | INIC | DNIC | ISI | ANIC
<maintainer> ::= maint: <place>
<update_notify> ::= updtnot: <datum>
<db_operation> ::= operation: <op_typ>
<op_type> ::= ADD | MODIFY | DELETE


/*********
  common elements
*********/
<organization> ::= 1[<org>] 0*[<address>] 1[<country>]
<org> ::= org: <datum>
<address> ::= addr: <datum>
<country> ::= cntry: <datum>
<contact> ::= <admin-contact> | <tech-contact>
<activated> ::= actvd: <datum>
<admin-contact> ::= admin-c: <email-address> | <nic_handle>
<tech-contact> ::= tech-c: <email-address> | <nic_handle>
<security-contact> ::= secur-c: <email-address> | <nic_handle>
<host_key> ::=  <datum>  /*either nic handle or ip number*/
<nic_handle> ::= nichandl: <datum>
<datum> ::= 1*[<alphanum>] NL

--------------------- TAG FIELD SEMANTICS -------------------------------

/******
  network-specific stuff
******/

ntnam: network name of network
ntnum: registered IP network number  [format: xxx.xxx.0.0 for class B
       xxx.xxx.xxx.0 for class C]
ntsblk: registered IP network number - start
nteblk: registered IP network number - end
ntype: network type - one of
        R = Research
        D = Defense
        G = Government
        C = Commercial
        E = Educational
actvd: Date in which the domain/network was initially registered 
   [format: YYMMDD]
inaddr-server: inaddress servers for the paticular network
   (either host ip address or hostname or nic handle )

/******
  domain-specific stuff
******/

dnam: domain name of domain. 
pdom: parent domain of domain (ie. NIC.DDN.MIL is DDN)
zone-c: zone contact (found in RFC 1032)
   (either mail-address or nic handle)
dns-server: servers for that paticular domain 
   (either host ip address or hostname or nic handle )

/******
  asn-specific stuff
******/

asnum: as number
as_sblk: as start number (of a block)
as_eblk: end number (of a block)
asin: accepted routes from other ASs (found in RIPE-81)
asout: routes announced to other ASs (found in RIPE-81)
asdefault: how default routing is handled (found in RIPE-81)
asguardian: guardian of this AS

/********
  host-specific stuff
********/

hname: hostname of host
nname: nickname(s) of host
ipaddr: IP address of host
cpu: cpu of host (found in RFC 1060)
opsys: operating system of host (found in RFC 1060)
proto: protocols supported by host (found in RFC 1060)
hmail: role mailbox of host administator

/*****
  individual-specific stuff
*****/

lname: last name of individual
fname: first name of individual
mname: middle initial of individual
nmsuf: name suffix of individual (ie JR., SR., ...)
ttle: title or rank (Capt., Lord, ...)
mbox: network mailbox of individual in internet format
phne: phone number of individual
fax: fax number of individual

/******
  common stuff
*******/

nichandl: handle given by the NIC 
org: organization name
addr: street address
cntry: country
source: originator of record (RIPE/MERIT/NIC)
updt: updated information (who/when) [format: YYMMDD-HHMM userid]
tech-c: technical coordinator of network/domain/host (found in RFC 1032)
   (either mail-address or nic handle)
admin-c: administrative coordinator of network/domain/host (found in RFC 1032)
   (either mail-address or nic handle)
secur-c: security coordinator of network/domain/host

----------------------- EXAMPLES ---------------------------------

INDIVIDUAL:

WDB_version: 1.0
---
lname:McColum
fname:Robert
mname:A
nmsuf:Jr.
ttle:Computer Developer Manager
nichandl:RM584
org:Government Systems, Inc.
addr:14200 Park Meadow Drive
addr:Suite 200
addr:Chantilly, VA 22021
cntry:US
mbox:bobm@localhost
phne:(703) 802-8476
updt:911029-120500 STANB
source:NIC
END OF FILE

-------------------------------------------------------------------------

NETWORK:

This is a sample network record that has:
  1) Peter Elford (PE33) is the tech contact.
  3) JATZ.AARNET.EDU.AU (AARNET) (already registered) as inaddr-server
  3) ANU.ANU.EDU.AU (ANU) (already registered) as inaddr-server
  4) MUNNARI.OZ.AU as a new inaddr-server

WDB_version: 1.0
---
ntnum:192.107.107.0
ntnam:AARN-DEV
ntype:Research
Nactvd:890203
org:Australian Academic and Research Network
addr:P.O. Box 1142
addr:Canberra ACT 2601
cntry:AU
tech-c:PE33
inaddr-server:AARNET
inaddr-server:ANU
inaddr-server:128.250.1.21
updt:910103-224721 STONED
source:RIPE
maint:RIPE
---
hname:JATZ.AARNET.EDU.AU
ipaddr:139.130.204.4
nichandl:AARNET
cputype:SUN-4/60
opsys:UNIX
protocols:UDP/DOMAIN
org:University of Melbourne
country: AU
uptd:900706-105714 MACGOWAN
source:NIC
maint:NIC
---
hname:ANU.ANU.EDU.AU
ipaddr:130.56.4.1
nichandl:ANU
cputype:MICROVAX-II
opsys:ULTRIX
protocols:UDP/DOMAIN
org:University of Melbourne
country: AU
updt:900706-105714 MACGOWAN
source:NIC
maint:NIC
---
hname:MUNNARI.OZ.AU
ipaddr:128.250.1.21
cputype:SUN-4/260
opsys:UNIX
protocols:UDP/DOMAIN
org:University of Melbourne
country: AU
updt:900705-105714 MACGOWAN
source:RIPE
maint:NIC
---
lname:Elford
fname:Peter
nichandl:PE33
org:Australian Vice Chancellors Committee
addr:Churchill House
addr:Northbourne Ave, Braddon
addr:GPO Box 1142
addr:Canberra ACT 2601
cntry:AU
mbox:p.elford@localhost
updated:900705-105714 MARKK
source:MERIT
maint:NIC
END OF FILE